本文將向您展示如何使用Qlik Sense構(gòu)建非常不同類(lèi)型的圖表。Qlik廣泛的圖表庫(kù)的一個(gè)非常聰明的補(bǔ)充，它說(shuō)明了當(dāng)我們用右眼觀(guān)看標(biāo)準(zhǔn)圖表時(shí)，如何提供更多標(biāo)準(zhǔn)圖表。 

如何逐步建立象限點(diǎn)圖？

您是否曾經(jīng)對(duì)Qlik Sense圖形對(duì)象感到限制？ 有時(shí)您或許想要一些與眾不同，令人驚訝或引人注目的東西。而面對(duì)這種情況，開(kāi)箱即用的功能就很重要了。

這是一個(gè)“圓點(diǎn)象限”圖表，接下來(lái)我們將介紹如何在Qlik中實(shí)現(xiàn)類(lèi)似目標(biāo)。

在本文中，我們不會(huì)討論何時(shí)或?yàn)槭裁词褂么丝梢暬?，我們只會(huì)專(zhuān)注于有關(guān)如何構(gòu)建它的更詳細(xì)指南，并且更一般地講，如何在Qlik中運(yùn)用基本圖形。

建立網(wǎng)格

首先，需要?jiǎng)?chuàng)建一個(gè)包含所有組成圖表的點(diǎn)的網(wǎng)格，將使用散點(diǎn)圖創(chuàng)建21 x 21的網(wǎng)格。請(qǐng)注意，由于需要界定每個(gè)扇區(qū)，因此是生成21 X 21的網(wǎng)格而不是20 x 20的網(wǎng)格。

生成腳本中的每個(gè)點(diǎn)

TMP:
LOAD RECNO() AS X AUTOGENERATE 21;
JOIN LOAD RECNO() AS Y AUTOGENERATE 21;

準(zhǔn)備數(shù)據(jù)

DATA :
LOAD X &'|'& Y AS POINT,
X+Y AS TOTAL,
X,Y
RESIDENT TMP;
DROP TABLE TMP;

使用散點(diǎn)圖并使用維度（稱(chēng)為點(diǎn)）和X Y作為度量來(lái)填充維度來(lái)創(chuàng)建點(diǎn)象限圖。將兩者的范圍都設(shè)置為22的最大值，并且有網(wǎng)格。

首先是刪除將四個(gè)部分分開(kāi)的點(diǎn)，使用X和Y即可輕松完成。在圖表中使用“按表達(dá)式”顏色將顏色設(shè)置為白色，以便它們從視圖中消失。

IF(X=Y OR X+Y=22, RGB(255,255,255))

要知道每個(gè)點(diǎn)屬于哪個(gè)“三角形”，可以使用以下條件：

if(Total=22 or X=Y,'NONE',
 if(Total>=23 and Y>X,'TOP',
  if(Total<23 and Y>X,'LEFT',
   if(Total>=23 and Y<X,'RIGHT',
    if(Total<23 and Y<X,'BOTTOM')))))

使用這些條件，您可以在腳本中生成一個(gè)名為“ POSITION”的新字段，該字段稍后將幫助您定位點(diǎn)象限圖的右四分之一。現(xiàn)在，您的加載腳本應(yīng)類(lèi)似于以下代碼：

TMP:
LOAD RECNO() AS X AUTOGENERATE 21;
JOIN
LOAD RECNO() AS Y AUTOGENERATE 21;
DATA:
// // DEFINE TRIANGLE POSITION
LOAD X,Y,TOTAL,POINT,
IF(TOTAL=22 OR X=Y,'NONE',
IF(TOTAL>=23 AND Y>X,'TOP',
IF(TOTAL<23 AND Y>X,'LEFT',
IF(TOTAL>=23 AND Y<X,'RIGHT',
IF(TOTAL<23 AND Y<X,'BOTTOM'))))) AS Position;
LOAD X&'|'&Y AS POINT,
X+Y AS TOTAL,
X,Y
RESIDENT TMP;
DROP TABLE TMP;

一旦知道了每個(gè)點(diǎn)的位置，就該為每個(gè)象限著色了。您可以按表達(dá)式重復(fù)使用“顏色”字段中的“位置”字段：

if(Position='NONE',rgb(255,255,255),
 if(Position='TOP',rgb(231, 76, 60),
  if(Position='RIGHT',rgb(41, 128, 185),
   if(Position='BOT',rgb(230, 126, 34),
    if(Position='LEFT',rgb(22, 160, 133)
)))))

在網(wǎng)格中顯示KPI

在示例中，有四個(gè)指標(biāo)和一個(gè)維度（年份），其中包含兩個(gè)值。由于每個(gè)四分之一由100個(gè)點(diǎn)組成，是時(shí)候從中心點(diǎn)開(kāi)始為它們分配一個(gè)從1到100的值了。這樣，您將可以控制各部分的填充方式，它們從中心向外填充。

在加載腳本中，是時(shí)候創(chuàng)建一個(gè)名為“ NoPoint”的新字段了，如下所示：

Top:
load Position,X,Y,RowNo() as NoPointT Resident Data
Where Position ='TOP'
Order by Y asc;
Right:
load Position,X,Y,rowno() as NoPointR Resident Data
Where Position ='RIGHT'
Order by X asc;
Bot:
load Position,X,Y,RowNo() as NoPointB Resident Data
Where Position ='BOT'
Order by Y desc;
Left:
load Position,X,Y,rowno() as NoPointL Resident Data
Where Position ='LEFT'
Order by X desc;
All:
LOAD Position,X,Y,NoPointT as NoPoint Resident Top;
Concatenate(All)
LOAD Position,X,Y,NoPointR as NoPoint Resident Right;
Concatenate(All)
LOAD Position,X,Y,NoPointB as NoPoint Resident Bot;
Concatenate(All)
LOAD Position,X,Y,NoPointL as NoPoint Resident Left;
join(Data)
LOAD * resident All;
Drop tables All,Top,Right,Bot,Left;

最后，返回到圖表顏色屬性面板，并添加每個(gè)KPI，例如：

Position='TOP' and Sum({$<Metric={'Sales'}>}Percentage)*100>=NoPoint

您的色彩表達(dá)應(yīng)該是這樣的：

if(X+Y=22 or X=Y,'#ffffff',
 if(Position='TOP' and Sum({$<Metric={'Sales'}>}Percentage)*100>=NoPoint,'#e74c3c',
  if(Position='RIGHT' and Sum({$<Metric={'Profit'}>}Percentage)*100>=NoPoint,'#2980b9',
   if(Position='BOT', 
    if(Sum({$<Metric={'Headcount'}>}Percentage)*100>=NoPoint,'#e67e22','#bdc3c7'),
     if(Position='LEFT', 
      if(Sum({$<Metric={'Cost'}>}Percentage)*100>=NoPoint,'#16a085','#bdc3c7')
,'#bdc3c7')
         )
        )
       )
      )

要完成圖表，請(qǐng)記住在其中隱藏不需要的內(nèi)容，X和Y以及Voila的標(biāo)簽和標(biāo)題。

點(diǎn)擊獲取Qlik

關(guān)于Qlik

Qlik的愿景是一個(gè)數(shù)據(jù)素養(yǎng)的世界，每個(gè)人都可以使用數(shù)據(jù)來(lái)改善決策并解決他們最具挑戰(zhàn)性的問(wèn)題。只有Qlik提供端到端的實(shí)時(shí)數(shù)據(jù)集成和分析解決方案，以幫助組織訪(fǎng)問(wèn)所有數(shù)據(jù)并將其轉(zhuǎn)化為價(jià)值。慧都作為Qlik官方的中國(guó)合作伙伴，我們?yōu)镼lik的中國(guó)用戶(hù)提供產(chǎn)品授權(quán)與實(shí)施、定制分析方案、技術(shù)培訓(xùn)等服務(wù)，旨在讓中國(guó)企業(yè)的每個(gè)Qlik用戶(hù)都能探索出數(shù)據(jù)的價(jià)值，讓企業(yè)形成分析文化。了解更多信息，請(qǐng)咨詢(xún)